home *** CD-ROM | disk | FTP | other *** search
/ Aminet 28 / Aminet 28 (1998)(GTI - Schatztruhe)[!][Dec 1998].iso / Aminet / util / libs / MMULib.lha / MMULib / Lib_Sources / PrintTTX.asm < prev    next >
Encoding:
Assembly Source File  |  1998-10-04  |  2.3 KB  |  102 lines
  1.         opt o+,ow-
  2. ;*************************************************
  3. ;** PrintTTx                                    **
  4. ;** Print the transparent translation registers **
  5. ;**                                             **
  6. ;** © 1998 THOR-Software                        **
  7. ;*************************************************
  8.  
  9.         include inc:exec_lib.asm
  10.         include inc:dos_lib.asm
  11.  
  12. ;FOLD Main structure
  13. ;*************************************************
  14. ;** Main structure                              **
  15. ;*************************************************
  16.         rsreset
  17. mn_SysBase:     rs.l 1
  18. mn_DOSBase:     rs.l 1
  19. mn_DTT0:        rs.l 1
  20. mn_DTT1:        rs.l 1
  21. mn_ITT0:        rs.l 1
  22. mn_ITT1:        rs.l 1
  23. mn_len:         rs.b 0
  24. ;ENDFOLD
  25.         machine mc68030
  26.  
  27. ;FOLD Start
  28. ;*************************************************
  29. ;** Start                                       **
  30. ;*************************************************
  31. Start:
  32.         lea BSSBase,a4
  33.         moveq #37,d0
  34.         move.l ExecBase,a6
  35.         lea DosName,a1
  36.         move.l a6,mn_SysBase(a4)
  37.         jsr OpenLibrary(a6)
  38.         move.l d0,mn_DOSBase(a4)
  39.         beq.s .nodos
  40.  
  41.  
  42.         btst #2,$129(a6)        ;mc68030?
  43.         beq.s .nodttx
  44.  
  45.         lea Fill030(pc),a5
  46.  
  47.         btst #3,$129(a6)        ;mc68040 or better ?
  48.         beq.s .got030
  49.  
  50.         lea Fill040(pc),a5
  51. .got030:
  52.         jsr Supervisor(a6)
  53.  
  54.         lea mn_DTT0(a4),a0
  55.         move.l mn_DOSBase(a4),a6
  56.         move.l #Fmt,d1
  57.         move.l a0,d2
  58.         jsr VPrintF(a6)
  59. .nodttx:
  60.         move.l mn_SysBase(a4),a6
  61.         move.l mn_DOSBase(a4),a1
  62.         jsr CloseLibrary(a6)
  63. .nodos:
  64.         moveq #0,d0
  65.         rts
  66. ;ENDFOLD
  67. ;FOLD Fill0x0
  68. Fill030:
  69.         pmove.l tt0,mn_dtt0(a4)
  70.         pmove.l tt1,mn_dtt1(a4)
  71.         rte
  72.  
  73.         machine mc68040
  74.  
  75. Fill040:
  76.         movec.l dtt0,d0
  77.         movec.l dtt1,d1
  78.         movem.l d0-d1,mn_dtt0(a4)
  79.  
  80.         movec.l itt0,d0
  81.         movec.l itt1,d1
  82.         movem.l d0-d1,mn_itt0(a4)
  83.         rte
  84.  
  85. ;ENDFOLD
  86.  
  87.         section main_data,data
  88. ;FOLD Data
  89. DOSName:        dc.b "dos.library",0
  90. Fmt:            dc.b "DTT0 :    0x%08lx",$0a
  91.                 dc.b "DTT1 :    0x%08lx",$0a
  92.                 dc.b "ITT0 :    0x%08lx",$0a
  93.                 dc.b "ITT1 :    0x%08lx",$0a
  94.                 dc.b 0
  95. ;ENDFOLD
  96.  
  97.         section main_bss,bss
  98. ;FOLD Bss
  99. BssBase:        ds.b mn_len
  100. ;ENDFOLD
  101.  
  102.